warning: unable to bind to property 'XX' on class 'Object' (class is not an IEventDispatcher)

When working with data pulled in from an HTTPService in Flex you may find that at run time your application spits out a bunch of warnings that it is unable to bind to a property.

If you want to prevent these warnings from occuring you should process your the data for your in actionscript instead of MXML.

Change this ...

<mx:Label text="{myresults.dynamiclabel}"/>

To this ... ( calling the function init() with the creationComplete event )

<mx:Script>
[Bindable] private var dynamiclabel:String;
private function init():void
{
 this.dynamiclabel = myresults.dynamiclabel;
}
</mx:Script>
<mx:Label text="{this.dynamiclabel}"/>

I know this approach requires a little bit more code and the first approach works, but this way it doesn't result in any warnings. I'll make the assumption that no run-time warnings means more compliant code.

Another approach to solving the problem is by wrapping Arrays in ArrayCollection and Objects in ObjectProxy wrappers. I got the following example from here.

function resultHandler(result:Array)
{
for(var i:String in result)
  {result[i] = new ObjectProxy(result[i]);}
targetArrayCollection = new ArrayCollection(result);
}

What about using ItemRenderer(s)?

If you are combining the use of an ItemRenderer and data from an HTTPService in your application you may find that neither of the above solutions fully work. What you really need is a modification of the first solution. Collecting your data in response to the creationComplete event will only collect data when the itemRenderer is first created. The event is not called when dynamically change the dataProvider. An approach to solving this scenario is the create a ChangeWatcher in the ItemRenderer to respond to changes to the data property of said ItemRenderer.

<mx:Script>
import mx.binding.utils.ChangeWatcher;
import mx.events.PropertyChangeEvent;

private var dataWatcher:ChangeWatcher;

[Bindable] private var dynamiclabel:String;

// ** Call this function from creationComplete event **
private function init():void
{
   this.dataWatcher = ChangeWatcher.watch( this, 'data', dataChangeHandler );
   this.dataChangeHandler(); 
}

private function dataChangeHandler(event:Event=null):void
{
   this.dynamiclabel = data.dynamiclabel;
}
</mx:Script>
<mx:Label text="{this.dynamiclabel}"/>